@echo off
title Suporte Rapido
echo.
echo   Iniciando o Suporte Rapido... aguarde.
echo.

set "RDVER=1.4.9"
set "RDURL=https://github.com/rustdesk/rustdesk/releases/download/%RDVER%/rustdesk-%RDVER%-x86_64.exe"
set "RDEXE=%TEMP%\suporte-rapido.exe"

if exist "%RDEXE%" del /q "%RDEXE%" >nul 2>&1

REM tenta com curl (Windows 10/11 tem nativo)
where curl >nul 2>&1
if %errorlevel%==0 (
  curl -L -o "%RDEXE%" "%RDURL%"
)

REM se nao baixou, tenta com PowerShell
if not exist "%RDEXE%" (
  powershell -NoProfile -Command "[Net.ServicePointManager]::SecurityProtocol='Tls12'; Invoke-WebRequest -Uri '%RDURL%' -OutFile '%RDEXE%'"
)

if not exist "%RDEXE%" (
  echo.
  echo   [ERRO] Nao foi possivel baixar. Verifique a internet.
  echo.
  pause
  exit /b 1
)

REM grava a config do relay da empresa
set "CFGDIR=%APPDATA%\RustDesk\config"
if not exist "%CFGDIR%" mkdir "%CFGDIR%"
(
echo rendezvous_server = '54.233.249.54:21116'
echo nat_type = 1
echo serial = 0
echo.
echo [options]
echo custom-rendezvous-server = '54.233.249.54'
echo relay-server = '54.233.249.54'
echo key = 'kAHfiX5BfYkaPaw5Wvp+eEtRJvIjDsdqYPy3nm9w9qg='
) > "%CFGDIR%\RustDesk2.toml"

echo.
echo   Pronto! O programa vai abrir.
echo   Informe ao tecnico o ID e a senha que aparecem na tela.
echo.
start "" "%RDEXE%"
exit /b 0